一键设置java 环境变量 cmd下查看、修改(覆盖与添加)等说明

一键设置java 环境变量 cmd下查看、修改(覆盖与添加)等说明,第1张

上来就给点干货吧

利用脚本,一键设置java环境变量(默认安装路径)

@echo off
color 0a
echo.------------------------------------
echo.TODO:设置java环境变量
echo.Author:Cheney_Yang
echo.Feedback E-mail:yangcheney@qq.com
echo.
echo.------------------------------------
::如果有的话,先删除JAVA_HOME
wmic ENVIRONMENT where "name='JAVA_HOME'" delete
::如果有的话,先删除ClASSPATH 
wmic ENVIRONMENT where "name='CLASSPATH'" delete
::创建JAVA_HOME
wmic ENVIRONMENT create name="JAVA_HOME",username="<system>",VariableValue="C:\Program Files (x86)\Java\jdk1.6.0_21"
::增加PATH中关于java的环境变量
wmic ENVIRONMENT where "name='path' and username='<system>'" set VariableValue="%path%;%JAVA_HOME%\bin;%JAVA_HOME%\jre\bin"
::创建CLASSPATH
wmic ENVIRONMENT create name="CLASSPATH",username="<system>",VariableValue=".;%JAVA_HOME%\lib\dt.jar;%JAVA_HOME%\lib\tools.jar;"
pause

安装JDK/安装JRE以及配置java环境变量对于java初学者来说是一件比较头疼的事情,这边分享一个简单的批处理命令,助大家一步完成JDK或者单独安装JRK的需求。

关键步骤:

1.新建一个.txt文档,复制附件一/附件二到文档中;

2.修改文档中的内容:

附件一:start /WAIT jdk-8u141-windows-i586.exe /qn INSTALLDIR=C:\Java\jdk1.8

附件二:start /WAIT jre-8u144-windows-i586.exe /s INSTALLDIR=C:\Java\jre

加红部分修改成你自己下载的JDK名字/JRE名字,注意:文档和软件请放在一个文件夹下

3.将.txt文档后缀修改成.bat后缀;

4.双击运行,最后就安装配置完成了。

一键设置java 环境变量 cmd下查看、修改(覆盖与添加)等说明,第2张

附件1(一键安装JDK和配置环境):

@echo off


%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

set myjdkpath=C:\Java\jdk1.8

echo **********************************************
echo.
echo     将要安装jdk
echo.
echo  安装请按任意键,退出直接关闭窗口
echo.
echo **********************************************

pause

echo.
echo 正在安装jdk,请不要执行其他操作
echo.
echo 请稍等,这个时间大约需要三、四分钟
echo.
start /WAIT jdk-8u141-windows-i586.exe /qn INSTALLDIR=C:\Java\jdk1.8
echo jdk安装完毕

set JAVA_HOME=C:\Java\jdk1.8
set PATH=%PATH%;%%JAVA_HOME%%\bin;%%JAVA_HOME%%\jre\bin
set CLASSPATH=.;%%JAVA_HOME%%\lib\dt.jar;%%JAVA_HOME%%\lib\tools.jar

set RegV=HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment

reg add "%RegV%" /v "JAVA_HOME" /d "%JAVA_HOME%" /f
reg add "%RegV%" /v "Path" /t REG_EXPAND_SZ /d "%PATH%" /f
reg add "%RegV%" /v "CLASSPATH" /d "%CLASSPATH%" /f
mshta vbscript:msgbox("Java环境已成功注册!",64,"成功")(window.close)

#-Dfile.encoding=utf-8

exit

附件二(一键安装JRE和配置环境):

@echo off


%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

set myjrepath=C:\Java\jre

echo **********************************************
echo.
echo   将要安装软件运行环境jre
echo.
echo  安装请按任意键,退出直接关闭窗口
echo.
echo **********************************************

pause

echo.
echo 正在安装jre,请不要执行其他操作
echo.
echo 请稍等,这个时间大约需要四、五分钟
echo.
start /WAIT jre-8u144-windows-i586.exe /s INSTALLDIR=C:\Java\jre
echo jre安装完毕

set JAVA_HOME=C:\Java
set PATH=%PATH%;%%JAVA_HOME%%\jre\bin
set CLASSPATH=.;%%JAVA_HOME%%\jre\lib

set RegV=HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment

reg add "%RegV%" /v "JAVA_HOME" /d "%JAVA_HOME%" /f
reg add "%RegV%" /v "Path" /t REG_EXPAND_SZ /d "%PATH%" /f
reg add "%RegV%" /v "CLASSPATH" /d "%CLASSPATH%" /f
mshta vbscript:msgbox("Java环境已成功注册!",64,"成功")(window.close)

exit

环境变量的作用:

它是操作系统用来指定运行环境的一些参数。比如临时文件夹位置和系统文件夹位置等。当你运行某些程序时,除了在当前文件夹中寻找外,还会到这些环境变量中去查找,比如“Path”就是一个变量,里面存储了一些常用的命令所存放的目录路径

人工设置也挺好的,就是如果批量或者新手就不容易了,这里为大家分享通过cmd设置的方法,需要的朋友可以参考一下。

永久设置与零时设置环境变量

使用set进行环境变量设置时,只对当前对话框程序有效。当cmd设置对话框关闭时,环境变量复原。如:

set PATH=%PATH%;C:\Program Files\

永久修改系统环境变量。使用setx 。如:

setx PATH "%PATH%;C:\Program Files\" /M

1、查看当前可用的所有环境变量(=系统变量+用户变量)

set

查看某个环境变量,如PATH

set PATH

添加环境变量,如xxx=aa

set xxx=aa

将环境变量(如xxx)的值置为空

set xxx=

在某个环境变量(如PATH)后添加新的值(如d:\xxx)

set PATH=%PATH%;d:\xxx

[注]:以命令行方式对环境变量的操作只对当前窗口的应用有效!

什么情况下设置:

当启动cmd命令行窗口调用某一命令的时候,经常会出现“xxx不是内部或外部命令,也不是可运行的程序或批处理文件”,如果你的拼写没有错误,同时计算机中确实存在这个程序,那么出现这个提示就是你的path变量没有设置正确,因为你的path路径,也就是默认路径里没有你的程序,同时你有没有给出你程序的绝对路径(因为你只是输入了命令或程序的名称而已),这是操作系统不知道去哪儿找你的程序,就会提示这个问题。

如何设置:

1、查看当前所有可用的环境变量

输入 set 即可查看。

2、查看某个环境变量

输入 “set 变量名”即可,比如想查看path变量的值,即输入 set path

3、修改环境变量 (覆盖)

输入 “set 变量名=变量内容”即可,比如将path设置为“d:\nmake.exe”,只要输入set path="d:\nmake.exe"。注意,此修改环境变量是指用现在的内容去覆盖以前的内容,并不是追加。比如当我设置了上面的path路径之后,如果我再重新输入set path="c",再次查看path路径的时候,其值为“c:”,而不是“d:\nmake.exe”;“c”。

4、设置为空

如果想将某一变量设置为空,输入“set 变量名=”即可。如“set path=” 那么查看path的时候就为空。注意,上面已经说了,只在当前命令行窗口起作用。因此查看path的时候不要去右击“我的电脑”——“属性”........

5、给变量追加内容(追加)

输入“set 变量名=%变量名%;变量内容”。如,为path添加一个新的路径,输入“ set path=%path%;d:\nmake.exe”即可将d:\nmake.exe添加到path中,再次执行"set path=%path%;c:",那么,使用set path语句来查看的时候,将会有:d:\nmake.exe;c:

如:

①追加、覆盖设置Path

set PATH=%PATH%;C:\Program Files\Microsoft SDKs\Windows\v6.0A\Lib;C:\Program Files\Microsoft SDKs\Windows\v6.0A\bin;C:\Program Files\Microsoft SDKs\Windows\v6.0A\include
set PATH=C:\Program Files\Microsoft Visual Studio\Common\Tools; C:\Program Files\Microsoft Visual Studio\Common\Tools\WinNT; C:\Program Files\Microsoft Visual Studio\Common\MSDev98\Bin; C:\Program Files\Microsoft Visual Studio\VC98\bin

②追加、覆盖设置LIB

set LIB=%LIB%;C:\Program Files\Microsoft SDKs\Windows\v6.0A\Lib
set LIB=C:\Program Files\Microsoft XML Parser SDK\lib;C:\Program Files\Microsoft Platform SDK\lib\;C:\Program Files\Microsoft Visual Studio\VC98\mfc\lib;C:\Program Files\Microsoft Visual Studio\VC98\lib

四、附录

下面是一些常用的环境变量
  %APPDATA% 局部 返回默认情况下应用程序存储数据的位置。cmd中运行:start “” “%APPDATA%” 或者 start %APPDATA%
  %COMSPEC% 系统 返回命令行解释器可执行程序的准确路径。
  

本文经用户投稿或网站收集转载,如有侵权请联系本站。